# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=tauthon-wxpython3
pkgver=3.0.2.0
pkgrel=2
pkgdesc="Classic wxWidgets GUI toolkit for Tauthon"
arch=('i686' 'x86_64')
license=('wxWindows-Library-3.1')
url='https://www.wxpython.org'
depends=('wxgtk3' 'tauthon')
makedepends=('mesa' 'glu')
provides=(wxpython=$pkgver)
source=("https://downloads.sourceforge.net/wxpython/wxPython-src-${pkgver}.tar.bz2"
        "fix-plot.patch"
        "fix-editra-removal.patch")
sha512sums=('a3798e89ff19344253aac7d771971e519f7fa9723e82bd97e98f16fd7f1572e513170b02295b872dae0b1ae3fa95efc4ef34d078045b839694b4fdad3a27c9e4'
            '6b4d235bbc67be66ae32c45b9ae8d2fd1aa6513d8625e1fa8af8f8399183ab598bd34ccd65158e113e8b99b86f3fd566e264d9bdeb681e68d634de17be29c473'
            '6cfe12b967088a9d9bc1e14f68a6b8a897bbfbf86fe22fa6b138fa32c71d6f14074f23af552a7bc34909b2d6adb8a775bd8a965bbdc15a9f814a99508ffd2ed6')

prepare() {
  find . -type f -exec sed -i 's/env python/env tauthon/' {} \;

  cd wxPython-src-${pkgver}/wxPython

  # Fix plot library
  patch -Np1 -i ${srcdir}/fix-plot.patch

  # Fix editra removal
  patch -Np2 -i ${srcdir}/fix-editra-removal.patch
}

build() {
  cd wxPython-src-${pkgver}

  ./configure \
        --prefix=/usr \
        --libdir=/usr/lib \
        --includedir=/usr/include \
        --with-gtk=3 \
        --with-opengl \
        --enable-unicode \
        --enable-graphics_ctx \
        --disable-precomp-headers \
        --with-regex=sys \
        --with-libpng=sys \
        --with-libxpm=sys \
        --with-libjpeg=sys \
        --with-libtiff=sys \
        --with-wx-config=/usr/bin/wx-config-gtk3

  cd wxPython
  tauthon setup.py WX_CONFIG=/usr/bin/wx-config-gtk3 WXPORT=gtk3 UNICODE=1 build
}

package() {
  cd wxPython-src-${pkgver}/wxPython

  tauthon setup.py WX_CONFIG=/usr/bin/wx-config-gtk3 WXPORT=gtk3 UNICODE=1 install --root="${pkgdir}" --optimize=1
  for file in "${pkgdir}"/usr/bin/*; do mv "${file}" "${file}2"; done
  install -Dm644 "${srcdir}/wxPython-src-${pkgver}/docs/licence.txt" -t "${pkgdir}"/usr/share/licenses/${pkgname}
}