# Maintainer: Jesus E. <heckyel@riseup.net>

_pkgname=pygobject
pkgname=tauthon-${_pkgname}2
pkgver=2.28.7
_pkgver=2.28
pkgrel=3
pkgdesc='Tauthon bindings for GObject'
arch=(i686 x86_64)
url='https://wiki.gnome.org/Projects/PyGObject'
license=(LGPL-2.1)
depends=(glib2 tauthon)
source=(https://download.gnome.org/sources/$_pkgname/$_pkgver/$_pkgname-$pkgver.tar.xz)
sha512sums=('a5f3ae39f8156bd6234fb6d0ea31eba782fbdd4c292656c31b33e098abe3dcf0774d492cf602a4637cb679af9ecd511b24263349fbfd25708ca70f16cb052dfb')

prepare() {
  cd $_pkgname-$pkgver
  find . \( -name '*.py' -o -name '*.py.in' \) -exec sed -i '1s|python|tauthon|' {} +
  autoreconf -fvi
}

build() (
  cd $_pkgname-$pkgver
  CPPFLAGS+=' -Wno-deprecated-declarations'
  ./configure --prefix=/usr --disable-introspection PYTHON=/usr/bin/tauthon
  sed -i 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
)

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  rm -r "$pkgdir/usr/share/gtk-doc"
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}