# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=tauthon-numpy
pkgver=1.16.2
_debver=$pkgver
_debrel=1
pkgrel=2
pkgdesc="Scientific tools for Tauthon"
arch=('i686' 'x86_64')
license=('Modified-BSD')
url="https://www.numpy.org/"
depends=('cblas' 'lapack' 'tauthon')
optdepends=('openblas: faster linear algebra')
makedepends=('tauthon-setuptools' 'gcc-fortran' 'tauthon-cython' 'quilt')
source=("$pkgname-$pkgver.tar.gz::https://github.com/numpy/numpy/archive/v$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-numpy/python-numpy_$_debver-$_debrel.debian.tar.xz")
sha512sums=('81f0f1826e64933948f7c5d5bd94ae3ffaad7c902762114b51110e7959bd08ec2c885187f42f961c151380b8eac810c797442f72afc2965ad939981eed458b3c'
            '1278cfae82e6d08add2eee8ccf38c97a350d293cb86b4c21e0b407f359e17f04fc6233e1f6da38065d468ed318d469d0ac8ccdcf817ad462ede9e091acd82ec8')

prepare() {
  cd numpy-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0005-Dont-fail-if-we-cant-import-mingw32.patch || true
    rm -v debian/patches/0006-disable-asserts-on-ppc-with-broken-malloc-only-longd.patch || true
    rm -v debian/patches/10_use_local_python.org_object.inv_sphinx.diff || true
    rm -v debian/patches/adapt_swig_docs_to_debian.patch || true
    rm -v debian/patches/python3-soabi.patch || true

    quilt push -av
  fi

  sed -e "s|#![ ]*/usr/bin/python$|#!/usr/bin/tauthon|" \
      -e "s|#![ ]*/usr/bin/env python$|#!/usr/bin/env tauthon|" \
      -e "s|#![ ]*/bin/env python$|#!/usr/bin/env tauthon|" \
      -i $(find . -name '*.py')
}

build() {
  cd numpy-$pkgver
  tauthon setup.py build
}

package() {
  cd numpy-$pkgver
  tauthon setup.py install --prefix=/usr --root="$pkgdir" --optimize=1

  mv "$pkgdir"/usr/bin/f2py{,-tauthon}

  install -Dm644 LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/LICENSE.txt
}