# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=taglib
pkgver=1.13
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="A free and libre library for reading and editing the meta-data of several popular audio formats"
arch=('i686' 'x86_64')
url='https://taglib.github.io/'
license=('LGPL-2.1')
depends=('zlib')
makedepends=('cmake' 'boost' 'utf8cpp' 'quilt')
source=("https://taglib.github.io/releases/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/t/taglib/taglib_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('b6e3253d158b41173073c0da1915f5e4a3de947db918660817cb1c755fba7e3723ea1a335fbbc30b0dcf942348a471b493fe2ce1d52d1a808578edee14e1bfc7'
            '049480fed54e14dba8f2cd75729e799d0e1584a28617c7ed658415500002c4024ad825274e33f24ce1075102882852a03ff9b7996da9d9da0be6f97832271a4e')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  export CPATH+=":/usr/include/utf8cpp"
  cmake \
    -B build \
    -S $pkgname-$pkgver \
    -D CMAKE_INSTALL_PREFIX=/usr \
    -D CMAKE_BUILD_TYPE=Release \
    -D CMAKE_CXX_FLAGS="$CXXFLAGS -DNDEBUG" \
    -D BUILD_SHARED_LIBS=ON \
    -Wno-dev
  make -C build
}

package() {
  make DESTDIR="$pkgdir" -C build install
  install -Dm644 $srcdir/$pkgname-$pkgver/COPYING.LGPL -t $pkgdir/usr/share/licenses/$pkgname
}