# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=supertux-legacy
pkgver=0.6.2
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="A classic, free and libre 2D jump'n'run sidescroller game (legacy version)"
arch=('i686' 'x86_64')
url='https://github.com/supertux/supertux'
license=('GPL-3')
provides=('supertux')
conflicts=('supertux')
depends=('sdl2_image' 'curl' 'openal' 'libvorbis' 'glew' 'physfs' 'freetype2' 'boost-libs' 'hicolor-icon-theme')
makedepends=('cmake' 'boost' 'mesa' 'optipng' 'quilt')
groups=('games')
source=("https://github.com/SuperTux/supertux/releases/download/v${pkgver}/SuperTux-v${pkgver}-Source.tar.gz"
        http://deb.debian.org/debian/pool/main/s/supertux/supertux_$_debver-$_debrel.debian.tar.xz)
sha512sums=('5baa783ee589b42a9bbce3740659dbb7b617ebfcc00c0a038c03d31b56700e3923c8548700ccebe42b325ca03bd85186bc5edef9f6580d93dc48d8aca88cbf74'
            'bb3c60bdad7100d2306251fbb2ae354affaaf23554d81540a200f02aeadada6c47a04b9dcae7aab3c4ca738cf2cb5f09457fd1e47a7da01641205a8c05afd57f')

prepare() {
  cd "SuperTux-v${pkgver}-Source"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "SuperTux-v${pkgver}-Source"

  cmake . \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DINSTALL_SUBDIR_BIN=games \
    -DCMAKE_BUILD_TYPE=Release \
    -Wno-dev
  make
}

package() {
  cd "SuperTux-v${pkgver}-Source"
  make DESTDIR="${pkgdir}" install
  install -Dm644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/$pkgname"
}