# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=subtitleeditor
pkgver=0.54.0
_debver=$pkgver
_debrel=5
pkgrel=1
pkgdesc="A GTK+3 tool to edit subtitles"
arch=('i686' 'x86_64')
url='https://kitone.github.io/subtitleeditor/'
license=('GPL-3')
depends=('desktop-file-utils' 'enchant' 'gst-plugins-base' 'gstreamermm' 'gst-libav'
         'gtkmm' 'hicolor-icon-theme' 'libsigc++' 'libxml++2.6' 'xdg-utils')
makedepends=('intltool' 'quilt' 'automake-1.15')
source=("https://github.com/kitone/$pkgname/releases/download/$pkgver/$pkgname-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/s/subtitleeditor/subtitleeditor_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('4458d579775a504b22f955c41d0e95ed722c1cb6bcf715ef493988a85397d5e0d4c3327e129f49b160d398dc73257026a92bbe5104c30d2004c16b7e12dd113c'
            '9e15c0f6d4ddc88650f6f7962b09175fddbae1c1ac295a83c33e29e1212f09a1d88711a4e1250c5f125d72ea02f4b77c3ca9f62594ee0010f0cf8d383fbe0832')

prepare() {
  cd "${srcdir}"/$pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/use_enchant-2.patch || true

    quilt push -av
  fi

  autoreconf -vfi
}

build() {
  cd "${srcdir}"/$pkgname-$pkgver

  ./configure --prefix=/usr
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package () {
  cd "${srcdir}"/$pkgname-$pkgver

  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}