# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=startup-notification
pkgver=0.12
pkgrel=8
pkgdesc="Monitor and display application startup"
arch=('i686' 'x86_64')
url='https://www.freedesktop.org/wiki/Software/startup-notification/'
license=('LGPL-2')
depends=('libx11' 'xcb-util')
source=("https://www.freedesktop.org/software/startup-notification/releases/${pkgname}-${pkgver}.tar.gz")
sha512sums=('ea1246acdb50dafd9ced9914ec3c8f0d499c0ca3cfd447b43a444c768a6e9ea7135e5c42d9ca0089354698ac235bd86d42f12c70a3a17c9c79f998c07461f7ab')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  sed -i -e '/AC_PATH_XTRA/d' configure.in
  autoreconf --force --install
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure \
    --prefix=/usr \
    --localstatedir=/var \
    --sysconfdir=/etc
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}