# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=squid
pkgver=4.13
_debver=$pkgver
_debrel=10
pkgrel=3
pkgdesc="Full-featured Web proxy cache server"
arch=('i686' 'x86_64')
url='http://www.squid-cache.org'
depends=('libressl' 'perl' 'libltdl' 'libcap' 'nettle' 'gnutls' 'libnsl' 'libxml2')
makedepends=('krb5' 'cppunit' 'quilt')
license=('GPL-2')
options=('emptydirs')
backup=('etc/squid/squid.conf'
	'etc/squid/cachemgr.conf'
	'etc/squid/errorpage.css'
	'etc/squid/mime.conf')
install=$pkgname.install
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/s/squid/squid_${pkgver}.orig.tar.xz"
        "https://security.debian.org/debian-security/pool/updates/main/s/squid/squid_${_debver}-${_debrel}+deb11u3.debian.tar.xz"
        "$pkgname.logrotate"
        "$pkgname.initd"
        "$pkgname.confd"
        "$pkgname.run")
sha512sums=('06807f82ed01e12afe2dd843aa0a94f69c351765b1889c4c5c3da1cf2ecb06ac3a4be6a24a62f04397299c8fc0df5397f76f64df5422ff78b37a9382d5fdf7fc'
            '79c25d8ef68e45c3ed263088cd2d6e68f484f576f4f185e4f7609051cdcf5987ee7c5acde5e5d11a13b023deccbd0a2d932962d389181ad111ea920910d6c8b6'
            '89a703fa4f21b6c7c26e64a46fd52407e20f00c34146ade0bea0c4b63d050117c0f8e218f2256a1fbf6abb84f4ec9b0472c9a4092ff6e78f07c4f5a25d0892a5'
            '6c9948ee452ea80f466da49e313c7ab5250f14c2c9248d0c27e1e176c1d89540dec23e91933057bd17484114c20ea82828ed7e2fea758ea718a67eb99db8a4ef'
            '018418d0ef66c9ab5d67a8e68ed6f95c7a04ad2a8a073747f39d9db8e83cf72c685d388a727363788042e45d440a69651ec928ccdeed835915ebc8c676b43519'
            '3c27f048f85e506b0d206be4fed035bc9e0d054b4ad5e09fbe7657478aea9ff232434194df324ca563f23672a29afd277766655c4074b62ba00018bc43233a14')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0001-Default-configuration-file-for-debian.patch || true
    rm -v debian/patches/0002-Change-default-file-locations-for-debian.patch || true
    rm -v debian/patches/0003-installed-binary-for-debian-ci.patch || true
    rm -v debian/patches/0005-Use-RuntimeDirectory-to-create-run-squid.patch || true

    quilt push -av
  fi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure \
    --prefix=/usr \
    --datadir=/usr/share/squid \
    --sysconfdir=/etc/squid \
    --libexecdir=/usr/libexec/squid \
    --localstatedir=/var \
    --with-logdir=/var/log/squid \
    --with-pidfile=/run/squid.pid \
    --enable-auth \
    --enable-auth-basic \
    --enable-auth-ntlm \
    --enable-auth-digest \
    --enable-auth-negotiate \
    --enable-removal-policies="lru,heap" \
    --enable-storeio="aufs,ufs,diskd,rock" \
    --enable-delay-pools \
    --enable-arp-acl \
    --with-openssl \
    --enable-snmp \
    --enable-linux-netfilter \
    --enable-ident-lookups \
    --enable-useragent-log \
    --enable-cache-digests \
    --enable-referer-log \
    --enable-arp-acl \
    --enable-htcp \
    --enable-carp \
    --enable-epoll \
    --with-large-files \
    --enable-arp-acl \
    --with-default-user=proxy \
    --enable-async-io \
    --enable-truncate \
    --enable-icap-client \
    --enable-ssl-crtd \
    --disable-arch-native \
    --disable-strict-error-checking \
    --enable-wccpv2
  make
}

package() {
  cd "$srcdir"

  make -C "$pkgname-$pkgver" DESTDIR="$pkgdir" install

  # initial data and configuration
  install -Dm644 "${srcdir}/$pkgname.logrotate" "$pkgdir/etc/logrotate.d/$pkgname"

  # license
  install -Dm644 "$pkgname-$pkgver/COPYING" -t "$pkgdir/usr/share/licenses/$pkgname"

  # services
  install -Dm644 "$srcdir/$pkgname.confd" "$pkgdir/etc/conf.d/$pkgname"
  install -Dm755 "$srcdir/$pkgname.initd" "$pkgdir/etc/init.d/$pkgname"
  install -Dm755 "$srcdir/$pkgname.run" "$pkgdir/etc/sv/$pkgname/run"

  # cleanup
  rm -rf "$pkgdir/run" "$pkgdir/var/run"
}