# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=spandsp
_pkgver=0.0.6+dfsg
pkgver=0.0.6
_debver=0.0.6+dfsg
_debrel=2
pkgrel=3
pkgdesc="A DSP library for telephony"
arch=('i686' 'x86_64')
license=('LGPL-2.1')
url="https://www.soft-switch.org/"
depends=('libtiff')
makedepends=('quilt')
source=(https://deb.debian.org/debian/pool/main/s/spandsp/spandsp_$_pkgver.orig.tar.xz
        https://deb.debian.org/debian/pool/main/s/spandsp/spandsp_$_debver-$_debrel.debian.tar.xz)
sha512sums=('f64765f849b38a20f1793b4792361e51b9c37d58701f72c46652f1512a3d15616ec8b5ad5833d68b6b7a6290bb3ae948ec22248cc3ff767cb8875a02ae0be8ef'
            '9d2969e33a6e9c683b092c16c2805487e2e3375b8cfa7ec159e73383b7ac856d8a1be691ff93a3d89835d758d81b8f8acbffb90b96fea21a61555dd4d1ff3a78')

prepare() {
  cd $pkgname-$_pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd $pkgname-$_pkgver
  ./configure --prefix=/usr
  make
}

check() {
   cd $pkgname-$_pkgver
   make check
}

package() {
  cd $pkgname-$_pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname
}