# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=spacefm
pkgname=('spacefm' 'spacefm-gtk2')
pkgver=1.0.6
_debver=$pkgver
_debrel=5
pkgrel=6
pkgdesc="Multi-panel tabbed file manager"
arch=('i686' 'x86_64')
url='https://ignorantguru.github.io/spacefm/'
license=('GPL-3')
conflicts=('spacefm')
provides=('spacefm')
makedepends=('gtk' 'gtk2' 'startup-notification' 'intltool' 'desktop-file-utils'
             'gettext-tiny' 'ffmpegthumbnailer' 'quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/IgnorantGuru/spacefm/archive/${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/s/spacefm/spacefm_$_debver-$_debrel.debian.tar.xz"
        "sysmacros.patch")
sha512sums=('37fc0dd31f02158502f592415b4c375ee49560af6f03d75b035d7c6c45bdc47064bba1ae8987b4cc8be2e02b3dfcdc17ec760411975e7b5f74343a2293fb2c8c'
            'dc2fc2a7be1478fdbefeac96c520647354d2c684be1a272022890deb72329c614bfbefffbfb1391337ffd10445371038635b485b6920d196a5d06203cda910fe'
            '58b75419b067fbe6cbe251c17055540fb2973f6e33b6d48af05af5f225c7b56e7959ee20d7ff53c869d539d0fe18ff7e5f4046af4a5b7e3349b92ecb3f28375e')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  # GTK+ 2 version
  [ -d gtk2 ] || cp -r $pkgbase-$pkgver gtk2
  cd gtk2
  patch -Np0 -b -z .orig < ${srcdir}/sysmacros.patch
  ./configure \
             --prefix=/usr \
             --with-gtk2 \
             --enable-video-thumbnails \
             --disable-pixmaps
  make

  # GTK+ 3 version
  cd "$srcdir"
  [ -d gtk3 ] || cp -r $pkgbase-$pkgver gtk3
  cd gtk3
  ./configure \
             --prefix=/usr \
             --with-gtk3 \
             --enable-video-thumbnails
  make
}

package_spacefm() {
  pkgdesc+=" (GTK+ 3 version)"
  depends=('gtk' 'startup-notification' 'ffmpegthumbnailer')
  optdepends=('lsof: device processes'
              'pmount: mount as non-root user')

  cd gtk3
  make DESTDIR="${pkgdir}" install
  rm -f "$pkgdir"/usr/bin/spacefm-installer
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}

package_spacefm-gtk2() {
  pkgdesc+=" (GTK+ 2 version)"
  depends=('gtk2' 'desktop-file-utils' 'startup-notification' 'ffmpegthumbnailer')
  optdepends=('lsof: device processes'
              'pmount: mount as non-root user')

  cd gtk2
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}