# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=sord
pkgver=0.16.8
_debver=0.16.8
_debrel=2
pkgrel=2
pkgdesc="A lightweight C library for storing RDF data in memory"
arch=('i686' 'x86_64')
url="https://drobilla.net/software/sord/"
license=('ISC')
depends=('glibc' 'serd' 'pcre')
makedepends=('waf' 'quilt')
source=("https://download.drobilla.net/${pkgname}-${pkgver}.tar.bz2"{,.asc}
        "https://deb.debian.org/debian/pool/main/s/sord/sord_$_debver-$_debrel.debian.tar.xz")
sha512sums=('24ed50de8e5bb321e557bac6d3e441b2ed49adabf828bf0e1b33a080c89306dde80443dc8b563098fcc184c4d6e53b7e716b523ddccdf56d08301d1b0120f2b2'
            'SKIP'
            'e0ca78cc289e6d3758d6da394954e600a2b4ab0aa2fc6a2d73a0c339444c574b769a772f2a3d0ecb47f950949af361b047e28f5e0b823f802806e4e4a15f3292')
validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3') # David Robillard <d@drobilla.net>

prepare() {
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  # remove local call to ldconfig
  sed -i "/ldconfig/d" wscript
  # let wscript(s) find the custom waf scripts
  mkdir -pv tools
  touch __init__.py
  cp -v waflib/extras/{autoship,autowaf,lv2}.py tools/
  mkdir -pv plugins/tools/
  cp -v waflib/extras/{autoship,autowaf,lv2}.py plugins/tools/
  rm -rv waflib
  sed -e 's/waflib.extras/tools/g' \
      -e "s/load('autowaf'/load('autowaf', tooldir='tools'/g" \
      -e "s/load('lv2'/load('lv2', tooldir='tools'/g" \
      -i wscript
}

build() {
  cd "${pkgname}-${pkgver}"
  waf configure --prefix=/usr \
                --test
  waf build
}

check() {
  cd "${pkgname}-${pkgver}"
  waf test
}

package() {
  cd "${pkgname}-${pkgver}"
  waf install --destdir="$pkgdir"
  # license
  install -vDm 644 COPYING \
    -t "$pkgdir/usr/share/licenses/$pkgname"
  # docs
  install -t "$pkgdir/usr/share/doc/${pkgname}" \
    -vDm 644 {AUTHORS,NEWS,README.md}
}

# vim:set ts=2 sw=2 et: