# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=smpeg
pkgver=0.4.5+cvs20030824
_debver=0.4.5+cvs20030824
_debrel=9
pkgrel=4
pkgdesc="SDL MPEG Player Library"
arch=(i686 x86_64)
url="https://icculus.org/smpeg/"
license=(LGPL-2)
depends=(sdl)
makedepends=(mesa glu quilt)
optdepends=('glu: to use glmovie')
source=("https://deb.debian.org/debian/pool/main/s/smpeg/smpeg_$pkgver.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/s/smpeg/smpeg_$_debver-$_debrel.debian.tar.xz")
sha512sums=('f5bdaf0adcc98210c2e47a007762f26a7c81a7f04dd52939e6d1a1b3e06ba389b41fe7a4d1ad72bf275fffe28f082560b6784a67585c607b8aae86fe163641b5'
            'd5b9d01cc8d3dc36a6fcc9b21bcd6351000a4abc981126730499378f13c1359e17fdd4118383ef91f53aefe62ede43486179e2f60ba85c50d2a8a977ef6ff0e9')

prepare() {
  cd $pkgname-$pkgver.orig
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd $pkgname-$pkgver.orig
  CFLAGS+=" -Wno-error=narrowing"
  ./configure --prefix=/usr --mandir=/usr/share/man --disable-static
  make
}

package() {
  cd $pkgname-$pkgver.orig
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname
}