# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=slrn
pkgver=1.0.3
_debver=$pkgver
_debrel=5
pkgrel=1
pkgdesc="A free and libre text-based news client"
arch=('i686' 'x86_64')
url="http://www.slrn.org/"
license=('GPL-2')
depends=('libressl' 'slang')
makedepends=('uudeview' 'quilt')
backup=('etc/slrnrc')
options=('!makeflags' 'docs' 'zipman')
source=("https://jedsoft.org/releases/slrn/slrn-${pkgver}a.tar.bz2"
        "https://deb.debian.org/debian/pool/main/s/slrn/slrn_${_debver}+dfsg-${_debrel}.debian.tar.xz")
sha512sums=('11cef2dfe41f441af15acc22fb675cf607e932f0dd6d4a998e51ecda05c9a50d7abf10a3e693ffc857ad77e09634f460404e4d5b289169e7bbffdaf5d6d565a3'
            'e7738777f67e7cd0fc21d2b0bdd361d61425e9186ebfc951344255ca4ab0835835ac19300ea8a08df0a7bb855ac5af0405d52ccbfef7634a952a2bd7df9c539b')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-setgid-code \
    --with-slrnpull \
    --with-ssl \
    --with-uu \
    --with-uulib=/usr/lib/uudeview \
    --with-uuinc=/usr/include/uudeview \
    --enable-spoilers
  make UUDEVIEW_LIB="/usr/lib/uudeview/*.o"
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  install -Dm644 doc/slrn.rc "$pkgdir/etc/slrnrc"
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}