# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=slop
pkgver=7.6
pkgrel=1
pkgdesc="Utility to query the user for a selection and print the region to stdout"
arch=('i686' 'x86_64')
url='https://github.com/naelstrof/slop'
license=('GPL-3')
depends=('libxext' 'libx11' 'mesa' 'glew' 'libxrender')
makedepends=('cmake' 'glm')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/naelstrof/slop/archive/v${pkgver}.tar.gz"
        "bugfix-add-missed-header.patch")
sha512sums=('d1abc50cad124cfb11e9b57c38c824efb2ece3dffce8e54e451ce4adc4a7ad441c6171b7df5d1c8dfa66c875a12cf07b206ba3b87229c0e5f2ddf744d7922fc3'
            '68b9813470f3f3ec8aff8b19783ee3c00e97d55ce25f08464fbe03764e23b7cbbe31560193a255a4a84b0d760c6a6ad0eafdc20a3103f71c6a0e3ce69f7a230f')

prepare() {
  cd "$pkgname-$pkgver"
  patch -Np1 -i ${srcdir}/bugfix-add-missed-header.patch
}

build() {
  cmake \
    -S $pkgname-$pkgver \
    -B build \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -Wno-dev
  make -C build
}

package() {
  make DESTDIR="$pkgdir" -C build install
  install -Dm644 "${srcdir}/$pkgname-$pkgver/COPYING" -t "${pkgdir}/usr/share/licenses/$pkgname"
}