# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=slang
pkgver=2.3.2
_debver=2.3.2
_debrel=5
pkgrel=1
pkgdesc='S-Lang is a powerful interpreted language'
arch=('i686' 'x86_64')
url="https://www.jedsoft.org/slang/"
license=('GPL-2')
depends=('pcre')
makedepends=('quilt')
backup=('etc/slsh.rc')
options=('!makeflags')
source=(https://www.jedsoft.org/releases/slang/${pkgname}-${pkgver}.tar.bz2{,.asc}
        https://deb.debian.org/debian/pool/main/s/slang2/slang2_${_debver}-${_debrel}.debian.tar.xz)
sha512sums=('35cdfe8af66dac62ee89cca60fa87ddbd02cae63b30d5c0e3786e77b1893c45697ace4ac7e82d9832b8a9ac342560bc35997674846c5022341481013e76f74b5'
            'SKIP'
            '67218b4a81cb1cd59e471eee7438e80ee5e41b4ebbca4022554cb6d1116be94b96cc8e1d3016411c80c1b503302e3187a230b55d238fa226157148bcea6d3b77')
validpgpkeys=('AE962A02D29BFE4A4BB2805FDE401E0D5873000A')  # John E. Davis

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr --sysconfdir=/etc
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install-all
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}