# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=signify
pkgver=31
_debver=$pkgver
_debrel=3
pkgrel=1
pkgdesc="OpenBSD tool to signs and verify signatures on files"
url='https://github.com/aperezdc/signify'
arch=('i686' 'x86_64')
license=('ISC')
depends=('glibc')
makedepends=('quilt')
source=("https://github.com/aperezdc/signify/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/s/signify-openbsd/signify-openbsd_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('f39597ea278a7eb10b786909752fde59e16405f0bc76c9906f8014e9e7f6801b4733479eec765fb960b6062359954caf54a3460ff67258a9cff93fa978951962'
            '1af3de02ad9c65338dd4ebd61ad68d53834957a7f91d17b22cc1c280cecadf5f0802f2245211add07d052551dddb44507e8d8737f398a372d9606322f97e467d')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0002-replace-signify-with-signify-openbsd.patch || true

    quilt push -av
  fi

  # using O_NOFOLLOW doesn't lock anything down here, swapping files
  # without symlinks is still equally open to TOCTOU and it doesn't even
  # matter here. lets prefere supporting symlinked target files.
  sed -E 's/\| ?O_NOFOLLOW//g' -i ./*.c
}

build () {
  cd ${pkgname}-${pkgver}
  make PREFIX=/usr \
    LTO=1 \
    EXTRA_CFLAGS="${CFLAGS} ${CPPFLAGS}" \
    EXTRA_LDFLAGS="${LDFLAGS}" \
    BUNDLED_LIBBSD=1 \
    GIT_TAG=''
}

package () {
  cd ${pkgname}-${pkgver}
  make PREFIX=/usr \
    DESTDIR="${pkgdir}" \
    BUNDLED_LIBBSD=1 \
    GIT_TAG='' install
  install -Dm 644 README.md CHANGELOG.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}