# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=sfml
pkgver=2.5.1
_debver=2.5.1+dfsg
_debrel=1
pkgrel=1
pkgdesc='A simple, fast, cross-platform, and object-oriented multimedia API'
arch=('i686' 'x86_64')
url='http://www.sfml-dev.org/'
license=('zlib')
depends=('libsndfile' 'libxrandr' 'openal' 'glew' 'freetype2' 'libx11')
makedepends=('mesa' 'cmake' 'doxygen' 'quilt')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/SFML/SFML/archive/${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/libs/libsfml/libsfml_${_debver}-${_debrel}.debian.tar.xz)
sha512sums=('7aed2fc29d1da98e6c4d598d5c86cf536cb4eb5c2079cdc23bb8e502288833c052579dadbe0ce13ad6461792d959bf6d9660229f54c54cf90a541c88c6b03d59'
            'de501f924d0e075dfef92cadbf95bc255365b9bdd9bd5b5395d10a2777109347d28a7e9797fdc558ae67a87b5a1945a9a0f02d8904acb00b86757ec3610184ac')

prepare() {
  cd SFML-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd SFML-${pkgver}

  mkdir build && cd build
  cmake .. \
      -DCMAKE_INSTALL_PREFIX=/usr \
      -DSFML_USE_SYSTEM_DEPS=ON \
      -DSFML_BUILD_EXAMPLES=1 \
      -DSFML_BUILD_DOC=1 \
      -DSFML_INSTALL_PKGCONFIG_FILES=1
  make
  make doc
}

package() {
  cd SFML-${pkgver}/build

  make DESTDIR="$pkgdir/" install

  install -Dm644 ../license.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
}