# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=sdl_ttf
pkgver=2.0.11
_debver=2.0.11
_debrel=6
pkgrel=1
pkgdesc='A library that allows you to use TrueType fonts in your SDL applications'
url='https://www.libsdl.org/projects/SDL_ttf/'
arch=('i686' 'x86_64')
license=('Modified-BSD')
depends=('sdl' 'freetype2')
makedepends=('quilt')
source=(https://www.libsdl.org/projects/SDL_ttf/release/SDL_ttf-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/s/sdl-ttf2.0/sdl-ttf2.0_$_debver-$_debrel.debian.tar.xz)
sha512sums=('64e04d1cd77e525e0f2413ad928841e5d3d09d551c030fc577b50777116580e430cb272b2aeb6191dfcc464669cf2f7a5a50d10e7c75637a3b1e8c8fca7fc78b'
            '23a5879efaf42e7aecc652a085824f32052ae2e4acb142b65d88a3c825a3d7dcd4cbd28a9daa5d4b360789bddab2fd3bcf5e2350ce66bbec4cc0ef7dbef747b6')

prepare() {
  cd SDL_ttf-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  touch NEWS README AUTHORS ChangeLog
  autoreconf -vi
}

build() {
  cd SDL_ttf-$pkgver
  ./configure --prefix=/usr --disable-static
  make
}

package() {
  cd SDL_ttf-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}