# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=sdl_sound
pkgver=1.0.3
_debver=1.0.3
_debrel=9
pkgrel=7
pkgdesc="A library to decode several popular sound file formats, such as .WAV and .MP3"
url="https://icculus.org/SDL_sound/"
arch=(i686 x86_64)
license=(LGPL-2.1)
depends=(sdl libmikmod libvorbis flac speex smpeg)
makedepends=(quilt)
source=(https://icculus.org/SDL_sound/downloads/SDL_sound-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/s/sdl-sound1.2/sdl-sound1.2_$_debver-$_debrel.debian.tar.xz)
sha512sums=('3e60671777d804e6104d7d441f4a29866492c9412040eea3fd2283c0914a0a1ebc550260631c2bf500e7d982e05a6f9feeda81e9eeef8257303750c1be582824'
            'd25026dbfafb141b3322651c8617cc16fe2f702fb8560a177d2be7f9d24796a55d403f9832982d28496d5cf7f197f4af0c7833333e494a17549c25e88bcf3606')

prepare() {
  cd SDL_sound-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd SDL_sound-$pkgver

  CFLAGS+=" -I/usr/include/smpeg"
  CXXFLAGS+=" -I/usr/include/smpeg"

  ./configure --prefix=/usr --disable-static
  make
}

package() {
  cd SDL_sound-$pkgver

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
}