# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=sdl_net
pkgver=1.2.8
_debver=1.2.8
_debrel=6
pkgrel=1
pkgdesc='A small sample cross-platform networking library'
url='https://www.libsdl.org/projects/SDL_net/'
arch=('i686' 'x86_64')
license=('zlib')
depends=('sdl')
makedepends=('quilt')
source=(https://www.libsdl.org/projects/SDL_net/release/SDL_net-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/s/sdl-net1.2/sdl-net1.2_$_debver-$_debrel.debian.tar.xz)
sha512sums=('2766ca55343127c619958ab3a3ae3052a27a676839f10a158f7dfc071b8db38c2f1fc853e8add32b9fef94ab07eaa986f46a68e264e8087b57c990af30ea9a0b'
            'ee3d75ac7cf3002c1274210d085ada6d9722421ef65ec5ed752deb939f475493d5359158de5a4254f5810fc89314706ded79e1af7dd5d53bca210ca3a9c140d4')

prepare() {
  cd SDL_net-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd SDL_net-$pkgver
  ./configure --prefix=/usr --disable-static
  make
}

package() {
  cd SDL_net-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}