# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=scribus
pkgver=1.5.8
_debver=$pkgver
_debrel=4
pkgrel=2
pkgdesc="Free and libre desktop publishing software"
arch=('i686' 'x86_64')
url='https://www.scribus.net/'
license=('GPL-2')
depends=('boost-libs' 'cairo' 'fontconfig' 'freetype2' 'harfbuzz-icu' 'hunspell' 'lcms2'
         'libcups' 'libjpeg-turbo' 'libpng' 'libtiff' 'libxml2' 'openscenegraph' 'libressl'
         'podofo' 'poppler' 'python' 'qt-base' 'zlib')
makedepends=('cmake' 'boost' 'mesa' 'qt-tools' 'quilt')
optdepends=('tk: for scripts based on tkinter')
source=("https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/s/scribus/scribus_${_debver}+dfsg-${_debrel}.debian.tar.xz")
sha512sums=('eb46be0165eeb0d8974aa744fc8ffac321b206ca0015da39bb2f50d9fd4a5e28300a49ada0f963b4e0cf9a3301dc746ffba74f359f5e76d308d80b71ee669c2d'
            '5eb94e90988b2963263db92b408a050c351757f5d6798cff4932413d01cb6733742b7e82583bee850a7cee15f64b2bd616a28157eb2c94dcdf89f8c146e8eb72')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cmake -B build -S ${pkgname}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_SKIP_RPATH=ON
  make -C build
}

package() {
  make -C build DESTDIR="${pkgdir}" install

  cd ${pkgname}-${pkgver}

  install -Dm644 scribus.desktop -t "${pkgdir}"/usr/share/applications

  for i in 16x16 32x32 128x128 256x256 512x512 1024x1024
  do
    install -Dm644 resources/iconsets/artwork/icon_${i}.png "${pkgdir}"/usr/share/icons/hicolor/${i}/apps/scribus.png
  done

  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}