# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=sawfish
pkgver=1.11.90
_debver=$pkgver
_debrel=1.2
pkgrel=3
pkgdesc="An extensible window manager using a Lisp-based scripting language"
arch=('i686' 'x86_64')
url='https://sawfish.wikia.com/wiki/Main_Page'
license=('GPL-2' 'Artistic-2.0')
depends=('libsm' 'rep-gtk' 'hicolor-icon-theme' 'gdk-pixbuf-xlib' 'libxtst' 'slock' 'zzz')
makedepends=('quilt')
optdepends=('lumina-core: support for Lumina-desktop')
options=('!libtool')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/s/sawfish/sawfish_${pkgver}.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/s/$pkgname/${pkgname}_${_debver}-${_debrel}.debian.tar.xz"
        "commands.patch")
sha512sums=('24735438167c1146e57f82a58876b68b1126d45f237751828ae9603a8eea966058fb6d8fbfddc28e1a96ab774a044b4b9b70b1e299f958b77eb32c987684925e'
            '6f49321ac85e06f3df1ff7ba1d1023dd165d6110fa33fa360bd53f99e8c0b45130392a0757fc6e2487bcb47aaee477c4d6f0ac5c081b6144c763b10844b795d8'
            '5be9a64fff3fcd11436c4c32d2207c7e5fd68098034e3e6da92d29b899d04fb8138c41d6f23b1bc35cc2a9bfd0765fb843de5f3867c3ef7309b085cf3b5d9a83')

prepare() {
  cd ${pkgname}_${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    cp -r "$srcdir"/debian .

    quilt push -av
  fi
  patch -p1 < "$srcdir"/commands.patch
  ./autogen.sh
}

build() {
  cd ${pkgname}_${pkgver}
  ./configure \
    --prefix=/usr \
    --without-kde4session \
    --without-kde5session \
    --without-matesession \
    --without-xfcesession \
    --without-gnome2session
  make
}

package() {
  cd ${pkgname}_${pkgver}
  make DESTDIR="${pkgdir}" install

  # cleanup, deleting unneeded and unsupported parts from package
  rm -rf "$pkgdir/usr/share/"{gnome,kde4,ksmserver}

  install -Dm644 sawfish.el -t "$pkgdir"/usr/share/emacs/site-lisp
  install -Dm644 lisp/sawfish/wm/tile/readme.org -t "$pkgdir"/usr/share/doc/$pkgname
  install -Dm644 COPYING COPYING.SOUNDS -t $pkgdir/usr/share/licenses/$pkgname
}