# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=runit
pkgname=(runit runit-sysvcompat)
pkgver=2.1.2
_debver=$pkgver
_debrel=41
pkgrel=6
pkgdesc="A UNIX init scheme with service supervision"
arch=('i686' 'x86_64')
url='http://smarden.org/runit/'
license=('Modified-BSD')
depends=('runit-init-scripts')
makedepends=('quilt')
source=(${pkgbase}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/r/runit/runit_${pkgver}.orig.tar.gz
        https://deb.debian.org/debian/pool/main/r/runit/runit_$_debver-$_debrel.debian.tar.xz
        runit-hook
        runit-install.hook
        runit-remove.hook
        30-sysctl.hook
        default-directory-for-services.patch)
sha512sums=('a18773ebf1aa22305dd89ed67363165b9fcf86c192b2be4e268d08005dd82d51265160c637abe072f2f2e378c4b315a75bd3d3e602c3e75bdd451a3b0190f8cf'
            '913077c52085bdcef3d40d512f662f21c2324ad5e93e5da6c2a3ab41c2d68a277c4d1fc270290d178f0a126a213b3bfd83357b93110de6fb43ceab031b3f04a8'
            '81b39ce971c5e1d23a7d6b8da9ae72553682a48a103112741ca78816776692d4db2d296c469acc786ad2eacbd4d149b5320763b35f0f0fa88c489bba08123faa'
            '4bdd02170955c07db37f02ba60d6bf3ed8f19f540330ef63db27845314de244bfd56f2e2212d98a1a2d9a9f253fa3bbc99cea47f49eee11f5a5c7e1252be9ef9'
            '4438c2cfa2de5ad84d3cd802a63288c43dde08c1f8f42bd92851250303fafc79ce84e1488cac76f86455e428881cf3dc47e2534f8a7e5a07e82f9a5e462c8001'
            '2af8331837dd8fcf1af8ed4f97b0c0fab8df8d0eb160ca38a5a1f6f3e7b484385cdc0bb099aa8fc20731903e059d2f30d6490156ccb2fcad9d9a967b954d57c1'
            'bb27a8bdfb5e932de138a473fc998acc2cec0799df2ca1bd02e6b521d64a1bcd5dc338b742437cb875bd1ed92c9e00164551a5f80729e592fdd383c6089d8c61')

prepare() {
  cd admin
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0001-default-directory-for-services-on-Debian-is-etc-servi.diff || true

    quilt push -av
  fi

  # set default service path to /var/service
  cd $pkgbase-$pkgver
  patch -p1 -i $srcdir/default-directory-for-services.patch
}

build() {
  cd admin/$pkgbase-$pkgver
  package/compile
}

package_runit() {
  cd admin/$pkgbase-$pkgver

  # create folders
  install -dm755 $pkgdir/sbin

  # commands
  install -Dm755 command/* $pkgdir/sbin

  # man pages
  install -dm755 $pkgdir/usr/share/man/man8
  install -Dm644 man/* $pkgdir/usr/share/man/man8

  # alpm hooks
  install -Dm755 $srcdir/runit-hook $pkgdir/usr/share/libalpm/scripts/runit-hook
  install -Dm644 -t $pkgdir/usr/share/libalpm/hooks $srcdir/*.hook

  # license
  install -Dm644 package/COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
}

package_runit-sysvcompat() {
  pkgdesc='SysV-style init compatibility for runit'
  depends=('runit')
  provides=('sysvinit')
  conflicts=('sysvinit')

  mkdir -p "${pkgdir}/sbin"
  cd "${pkgdir}/sbin"
  ln -s runit-init init
  for i in halt shutdown; do
    ln -s runit-$i $i
  done
  for i in poweroff reboot; do
    ln -s halt $i
  done

  mkdir -p "${pkgdir}/usr/share/man/man8"
  cd "${pkgdir}/usr/share/man/man8"
  ln -s runit.8.gz init.8.gz
  for i in halt shutdown; do
    ln -s runit-$i.1.gz $i.1.gz
  done
  for i in poweroff reboot; do
    ln -s halt.1.gz $i.1.gz
  done

  # license
  install -Dm644 "${srcdir}/admin/${pkgbase}-${pkgver}/package/COPYING" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}