# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=runit-init-scripts
pkgver=0.2
pkgrel=2
pkgdesc='runit init scripts'
arch=(i686 x86_64)
url='https://git.hyperbola.info:50100/software/runit-init-scripts.git'
license=(CC0-1.0)
depends=(procps-ng)
conflicts=(hyperrc) # conflicts with rc.conf
backup=(etc/rc.conf
        etc/rc.local
        etc/rc.shutdown
        etc/sv/agetty-console/conf
        etc/sv/agetty-serial/conf
        etc/sv/agetty-tty1/conf
        etc/sv/agetty-hvc0/conf
        etc/sv/agetty-hvsi0/conf)
install=$pkgname.install
source=(https://repo.hyperbola.info:50000/sources/$pkgname/$pkgname-v$pkgver.tar.lz{,.sig})
sha512sums=('ca059882568c63af7bf7f6e24316fd3a2677139d61c41ac85343ff1155892f17f1779de08c320d62a2722186a5920cf081226c994c6de1cf806318ad1df583c2'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

build() {
  cd $pkgname-v$pkgver
  make
}

package() {
  cd $pkgname-v$pkgver
  make PREFIX=/usr DESTDIR="$pkgdir" install

  # halt and shutdown are used by runit-sysvcompat
  for i in halt shutdown; do
    mv "${pkgdir}/sbin/$i" "${pkgdir}/sbin/runit-$i"
    mv "${pkgdir}/usr/share/man/man8/$i.8" \
      "${pkgdir}/usr/share/man/man8/runit-$i.1"
  done

  # poweroff and reboot are used by runit-sysvcompat
  for i in poweroff reboot; do
    rm "${pkgdir}/sbin/$i"
    rm "${pkgdir}/usr/share/man/man8/$i.8"
  done

  # license
  install -Dm644 legalcode.txt $pkgdir/usr/share/licenses/$pkgname/legalcode.txt
}