# Maintainer: Jesus E. <heckyel@riseup.net>

_gemname=ronn-ng
pkgname=ruby-$_gemname
pkgver=0.9.1
_debver=$pkgver
_debrel=3
pkgrel=4
pkgdesc="Manual page formatter that generates man pages from markdown"
arch=('any')
url='https://github.com/apjanke/ronn-ng'
license=('Expat')
depends=('ruby' 'ruby-hpricot' 'ruby-rdiscount' 'ruby-mustache' 'ruby-kramdown' 'ruby-nokogiri')
makedepends=('quilt')
options=(!emptydirs)
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/apjanke/${_gemname}/archive/refs/tags/v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/r/ruby-ronn/ruby-ronn_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('03d6856598740ff670a500b182d0be84b584c98245e81b605de6c126b79680be48d2ed18d4cf28252c0a82883b4740ae58c584e977d3f0a9480082a9eb560a9a'
            '55031716ea24109fd1b52f3f3ba308517ece73a97689d1cbd61a60e99a6ccca81c353736fb937099b7c0f4d359cf3c73bab4c334c1f3faf9c8ef9aaea673f1b5')

prepare() {
  cd $_gemname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build () {
  cd $_gemname-$pkgver
  gem build
}

package() {
  cd $_gemname-$pkgver
  local _gemdir="$(ruby -e'puts Gem.default_dir')"
  gem install --ignore-dependencies --no-user-install -i "$pkgdir/$_gemdir" -n "$pkgdir/usr/bin" $_gemname-$pkgver.gem
  rm "$pkgdir/$_gemdir/cache/$_gemname-$pkgver.gem"
  install -D -m644 "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/LICENSE.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"

  install -D -m644 "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/man/ronn.1" "$pkgdir/usr/share/man/man1/ronn.1"
  install -D -m644 "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/man/ronn-format.7" "$pkgdir/usr/share/man/man7/ronn-format.7"

  install -D -m644 "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/completion/bash/ronn" "$pkgdir/usr/share/bash-completion/completions/ronn"
  install -D -m644 "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/completion/zsh/_ronn" "$pkgdir/usr/share/zsh/site-functions/_ronn"
}