# Maintainer: Jesus E. <heckyel@riseup.net>

_gemname=hpricot
pkgname=ruby-$_gemname
pkgver=0.8.6
_debver=$pkgver
_debrel=6
pkgrel=2
pkgdesc="A swift, liberal HTML parser with a fantastic library"
arch=('i686' 'x86_64')
url='https://github.com/hpricot/hpricot'
license=('Expat')
depends=('ruby')
makedepends=('quilt')
options=(!emptydirs)
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/hpricot/hpricot/archive/refs/tags/${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/r/${pkgname}/${pkgname}_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('0b35295745d36483fbd0c0ea7751c9e9672efdc3738145991a4799e3e2f75ec05cc833b28eacb45631a805b760b6f83a179bbbd830a3b30ea25749d243f527d7'
            '2d01c9eed6d6ae6463c16fcd404528d0a80d77bc763e573a83e6bb5c958b57b64b273ab46aa9366b149780300ed77b6f4bc0751360d59fa3711dfe154a1b8d99')

prepare() {
  cd $_gemname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build () {
  cd $_gemname-$pkgver
  gem build
}

package() {
  cd $_gemname-$pkgver
  local _gemdir="$(ruby -e'puts Gem.default_dir')"
  gem install --ignore-dependencies --no-user-install --no-document -i "$pkgdir/$_gemdir" -n "$pkgdir/usr/bin" $_gemname-$pkgver.gem
  rm "$pkgdir/$_gemdir/cache/$_gemname-$pkgver.gem"
  rm -r "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/test"
  install -D -m644 "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/COPYING" -t "$pkgdir/usr/share/licenses/$pkgname"

  rm -r "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/ext"
}