# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=ri-li
pkgver=2.0.1
pkgrel=1
pkgdesc="Drive a toy wood engine in many levels and collect all the coaches to win"
arch=('i686' 'x86_64')
url="http://ri-li.sourceforge.net/"
license=('GPL-2' 'GPL-3')
depends=('gcc-libs' 'sdl_mixer')
groups=('games')
source=(https://downloads.sourceforge.net/sourceforge/$pkgname/Ri-li-$pkgver.tar.bz2
        iostream.patch
        ri-li.desktop)
sha512sums=('6d56c00dae90b50bca81ca739c628335b4ad7642c19a3b3c28630ddb91bd847ca6d383cace66ef436a1dda7497c9d3939de2626071bae40d423b2444fed97863'
            '49fbf3a30f0ae6c47d8fcc45d72891ac199187f7615840f6eb994df998440980d7838beceec5225325c2e971c97dbc28a02ad47db03d144bb9cd90b18d4422e8'
            'cba2c93be02ad90ffda4fd637df347f3a88d43548c61d60bf06050cac5e6d9d379b6232a86925049903dbf7eabf9355977e17c568042341e1091af358932393f')

prepare() {
  mv Ri-li-$pkgver $pkgname-$pkgver
  cd $pkgname-$pkgver
  patch -p1 < $srcdir/iostream.patch
  autoreconf -vfi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --bindir=/usr/games \
    --datadir=/usr/share/games
  sed -i "s/SUBDIRS = src data Sounds gentoo/SUBDIRS = src data Sounds/" Makefile
  make || return 1
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR=$pkgdir install

  install -m644 -D $srcdir/ri-li.desktop $pkgdir/usr/share/applications/ri-li.desktop
  install -m644 -D data/Ri-li-icon-48x48.png $pkgdir/usr/share/pixmaps/ri-li.png
  install -Dm644 {COPYING,COPYING.Music} -t "${pkgdir}"/usr/share/licenses/$pkgname
}