# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=re2c
pkgver=2.0.3
_debver=2.0.3
_debrel=1
pkgrel=1
arch=(i686 x86_64)
pkgdesc='A tool for generating C-based recognizers from regular expressions'
url='https://re2c.org'
license=(Public-Domain)
depends=(gcc-libs)
makedepends=(quilt)
source=(re2c-$pkgver.tar.gz::https://github.com/skvadrik/re2c/archive/$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/r/re2c/re2c_$_debver-$_debrel.debian.tar.xz)
sha512sums=('11fe3a0a38fbc378f6c54e418c3557a9bd21dd9b693b1efbf98cb0a52683d1932bbb1e253cb048fddb0c0c9b33f58dcaa2d1294cb1bc7b6ee9e8fb9d827219c5'
            '9944f0c9e9df284c858a0c8b8709cd2bf73b4a5795e6bd9ba4fe006e2b36419e10dc57b8b3f05fcda1c0e248337482d8c7d857749b13acad808aa95dfd5df52f')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  ./autogen.sh
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

check() {
  cd $pkgname-$pkgver
  make tests
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
}