# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=radicale
_name=Radicale
pkgver=3.0.6
_debver=$pkgver
_debrel=3
pkgrel=2
pkgdesc='Simple calendar (CalDAV) and contact (CardDAV) server'
arch=('any')
url='https://radicale.org/'
license=('GPL-3')
depends=('python-bcrypt' 'python-dateutil' 'python-defusedxml' 'python-passlib'
         'python-setuptools' 'python-vobject')
makedepends=('quilt')
backup=('etc/radicale/config'
        'etc/radicale/rights'
        'etc/radicale/users')
install="${pkgname}.install"
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/Kozea/${pkgname}/archive/${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/r/radicale/radicale_${_debver}-${_debrel}.debian.tar.xz"
        "${pkgname}.initd"
        "${pkgname}.run")
sha512sums=('e9741547395fae8886ad84b6807422ebb196f5293d484f5f6136498058576cff697e28c117216f151d56494af83593347ceee40a6efa21272b803d0f301a396d'
            '0d7652fa3c7353c058b8ecc759cd7128f5178e51a988ea1897b6818cfbe30e20342dd0b325c9d5b56d8a2c7668a861881e0f693182cacea2594fe2bac00fac22'
            '61c2e8d3d4a992e2b4fba9c4c3176b052baa63fcdb643bbc82af23f6d4e6171ed23d4b819f96f9bcc660065b525678f52b3cc17b7ec1ae70ab358dd9aefd72ea'
            'fd89c84696cc54decd50d91cc9f17cdc5ffab79c0003ba943429cafd4adc9b0dcd6e6c51d606bdc7e5a915a2b3a0d657e9e90178f699013011ee00889e19558f')

prepare() {
  mv -v ${_name}-${pkgver} ${pkgname}-${pkgver}
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # removing flake8, isort and coverage
  sed -e '/addopts/d' -i setup.cfg
  touch "users"
}

build() {
  cd "${pkgname}-${pkgver}"
  python setup.py build
}

package() {
  cd "${pkgname}-${pkgver}"
  python setup.py install --skip-build \
                          --optimize=1 \
                          --root="${pkgdir}"

  # config
  install -vDm 644 {config,rights,users} -t "${pkgdir}/etc/${pkgname}/"
  install -d -m750 "$pkgdir"/var/lib/$pkgname

  # wsgi
  install -vDm 644 "${pkgname}.wsgi" -t "${pkgdir}/usr/share/${pkgname}/"

  # services
  install -Dm755 "${srcdir}/${pkgname}.initd" "${pkgdir}/etc/init.d/${pkgname}"
  install -Dm755 "${srcdir}/${pkgname}.run" "${pkgdir}/etc/sv/${pkgname}/run"

  # docs
  install -vDm 644 {NEWS,README}.md -t "${pkgdir}/usr/share/doc/${pkgname}/"

  # license
  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}