# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=qt-xmlpatterns
_pkgbasename=qtxmlpatterns
_qtver=5.15.2
pkgver=${_qtver/-/}
_debver=5.15.2
_debrel=3
pkgrel=1
arch=('i686' 'x86_64')
url='https://www.qt.io'
license=('LGPL-3')
pkgdesc='Support for XPath, XQuery, XSLT and XML schema validation'
depends=('qt-base')
makedepends=('qt-declarative' 'quilt')
optdepends=('qt-declarative: QML bindings')
groups=('qt')
_pkgfqn="${_pkgbasename/5-/}-everywhere-src-${_qtver}"
source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz"
        "https://deb.debian.org/debian/pool/main/q/qtxmlpatterns-opensource-src/qtxmlpatterns-opensource-src_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('5cdf51878f8bb42db57110acc0c3985a95af098da44e5dda505e0716fef5afc780419058158f7a8f9a0fe3fed83fd64abd856b4dbcdca20efa5e985fa85cc348'
            '8bc2e7fa7365b94a6fd125a8ab6b1053c349f7d1dc95c5ec03d2a58a1aa40450e81d963665ed457eeed9e65f0d186b09b2b180226f5bb910a410bc8339201b72')

prepare() {
  cd ${_pkgfqn}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  mkdir -p ../build
}

build() {
  cd build

  qmake ../${_pkgfqn}
  make
}

package() {
  cd build
  make INSTALL_ROOT="$pkgdir" install

  # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
  find "$pkgdir/usr/lib" -type f -name '*.prl' \
    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;

  # Install license
  install -D -m644 "${srcdir}"/${_pkgfqn}/LICENSE.LGPL3 "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.LGPL3
}