# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-zope-component
pkgname=('python-zope-component' 'tauthon-zope-component')
pkgver=4.3.0
_debver=$pkgver
_debrel=3
pkgrel=2
pkgdesc="Represents the core of the Zope Component Architecture"
arch=('any')
url="https://github.com/zopefoundation/zope.component"
license=('Zope-2.1')
makedepends=('python-setuptools' 'tauthon-setuptools'
             'python-zope-interface' 'tauthon-zope-interface'
             'python-zope-event' 'tauthon-zope-event'
             'quilt')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/zopefoundation/zope.component/archive/$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/z/zope.component/zope.component_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('ac543f4db31a39ec64588ac000fc9e9d49e1192c340e991373d84c436b6d1d39e29707d58f88aaad74e613278b124576bfc1263c21c3bda5031251f3886859d8'
            '076c950e5db56661bc3ef523d498359b22f13b3fba72b0d46cfc6dcf24468f4a173d958e439bff0b46e50041c6df8cef79227b44ed2084131b53e81b1bd4d8b9')

prepare() {
  cd "$srcdir/zope.component-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  cp -a $srcdir/zope.component-$pkgver{,-tauthon}
}

build() {
  cd "$srcdir/zope.component-$pkgver"
  python setup.py build

  cd "$srcdir/zope.component-$pkgver-tauthon"
  tauthon setup.py build
}

package_python-zope-component() {
  depends=('python-setuptools' 'python-zope-interface' 'python-zope-event')
  cd "$srcdir/zope.component-$pkgver"
  python setup.py install --root="$pkgdir/" --optimize=1
  install -Dm644 LICENSE.txt -t $pkgdir/usr/share/licenses/$pkgname
}

package_tauthon-zope-component() {
  depends=('tauthon-setuptools' 'tauthon-zope-interface' 'tauthon-zope-event')
  cd "$srcdir/zope.component-$pkgver-tauthon"
  tauthon setup.py install --root="$pkgdir/" --optimize=1
  install -Dm644 LICENSE.txt -t $pkgdir/usr/share/licenses/$pkgname
}