# Maintainer: Jesus E. <heckyel@riseup.net>

_pkgname=snowballstemmer
pkgbase=python-snowballstemmer
pkgname=('python-snowballstemmer' 'tauthon-snowballstemmer')
pkgver=2.0.0
pkgrel=2
arch=('any')
pkgdesc="Snowball stemming library collection"
url='https://snowballstem.org'
license=('Modified-BSD')
makedepends=('python-setuptools' 'tauthon-setuptools' 'quilt')
source=("https://pypi.python.org/packages/source/s/snowballstemmer/$_pkgname-$pkgver.tar.gz")
sha512sums=('d673205cacc7f6e81eaee23e6c50064af77c3c4464dbdf5dc1c3f5682dec2688fe6e7069b7ed2e59259312ba926d3be84bd846a132b6138e30b4ff2b9a9353e8')

prepare() {
  cp -av $_pkgname-$pkgver{,-tauthon}
}

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  python setup.py build

  cd "$srcdir/$_pkgname-$pkgver-tauthon"
  tauthon setup.py build
}

package_python-snowballstemmer() {
  pkgdesc+=" for Python"
  depends=('python')

  cd "$srcdir"/$_pkgname-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1
  install -d "$pkgdir/usr/share/licenses/$pkgname"
  install -m644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}

package_tauthon-snowballstemmer() {
  pkgdesc+=" for Tauthon"
  depends=('tauthon')

  cd "$srcdir"/$_pkgname-$pkgver-tauthon
  tauthon setup.py install --root="$pkgdir" --optimize=1
  install -d "$pkgdir/usr/share/licenses/$pkgname"
  install -m644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}