# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=python-pysnmp
_pyname=pysnmp
pkgver=4.4.12
_debver=$pkgver
_debrel=1
pkgrel=2
pkgdesc="Free and libre implementation of v1/v2c/v3 SNMP engine"
url='https://github.com/etingof/pysnmp'
arch=('any')
license=('Simplified-BSD')
depends=('python' 'python-pysmi' 'python-pyasn1')
makedepends=('python-setuptools' 'python-sphinx' 'quilt')
options=('!makeflags')
source=("https://github.com/etingof/pysnmp/archive/v${pkgver}/${_pyname}-v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-pysnmp4/python-pysnmp4_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('48481e219098369b09cc2ffea6cd51974b64bed0131671cc7a2213ee5eb432c62e0ff5c3700b6be515bd3e90951927e41845c98ae7a339d551f0f4ec19c5e3b1'
            '6b0ca84523b016cd76c6d8ca248db02e40f7d82d178919d8e55cc5a80439e6b0cae09bc80ca9868f6682ec44bee903c0479fc4bcd735f3e6424fbedf02213840')

prepare() {
  cd ${_pyname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${_pyname}-${pkgver}
  export PYTHONPATH=.
  python setup.py build
  make -C docs text man
}

package() {
  cd ${_pyname}-${pkgver}
  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build

  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  cp -r docs/build/text "${pkgdir}/usr/share/doc/${pkgname}"
  cp -r examples -t "${pkgdir}/usr/share/doc/${pkgname}"

  install -Dm 644 docs/build/man/${_pyname}.1 "${pkgdir}/usr/share/man/man1/${_pyname}.1"
  install -Dm 644 docs/build/man/${_pyname}.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
  install -Dm 644 LICENSE.rst -t "${pkgdir}/usr/share/licenses/${pkgname}"
}