# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-lxml
pkgname=('python-lxml' 'tauthon-lxml')
pkgver=4.6.0
pkgrel=3
arch=('i686' 'x86_64')
license=('Modified-BSD')
url="https://lxml.de/"
makedepends=('libxslt' 'python-setuptools' 'tauthon-setuptools' 'tauthon-pygments' 'python-cython' 'tauthon-cython')
source=("https://github.com/lxml/lxml/archive/lxml-$pkgver.tar.gz")
sha512sums=('b92403b68babac8112ec87989909eb03b75ad365bcd938daef11f4768e95d9bc7a53dae90882d22eeb51bc1a04ae47f8deac504e426b1751826575280655c19e')

prepare() {
  mv lxml-lxml-$pkgver lxml-$pkgver
  cp -a lxml-$pkgver{,-tauthon}

  # Setting LC_CTYPE to workaround encoding issue
  export LC_CTYPE=en_US.UTF-8

  cd lxml-$pkgver-tauthon
  sed -i 's|2, 7|2, 8|' setup.py
}

build() {
  cd "$srcdir"/lxml-$pkgver
  python setup.py build

  cd "$srcdir"/lxml-$pkgver-tauthon
  tauthon setup.py build
}

package_python-lxml() {
  pkgdesc="Python binding for the libxml2 and libxslt libraries"
  depends=('python' 'libxslt')
  optdepends=('python-beautifulsoup4: support for beautifulsoup parser to parse not well formed HTML')

  cd lxml-$pkgver
  python setup.py install --root="$pkgdir" --skip-build --optimize=1

  install -Dm644 LICENSES.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/LICENSES.txt
  install -Dm644 doc/licenses/BSD.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/BSD.txt
  install -Dm644 doc/licenses/elementtree.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/elementtree.txt
}

package_tauthon-lxml() {
  pkgdesc="Tauthon binding for the libxml2 and libxslt libraries"
  depends=('tauthon' 'libxslt')
  optdepends=('tauthon-beautifulsoup4: support for beautifulsoup parser to parse not well formed HTML')

  cd lxml-$pkgver-tauthon
  tauthon setup.py install --root="$pkgdir" --skip-build --optimize=1

  install -Dm644 LICENSES.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/LICENSES.txt
  install -Dm644 doc/licenses/BSD.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/BSD.txt
  install -Dm644 doc/licenses/elementtree.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/elementtree.txt
}