# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-jinja
pkgname=('python-jinja' 'tauthon-jinja')
pkgver=2.11.3
_debver=$pkgver
_debrel=1
pkgrel=3
pkgdesc="A simple template language"
arch=('any')
url='https://palletsprojects.com/p/jinja/'
license=('Modified-BSD')
makedepends=('python-setuptools' 'tauthon-setuptools' 'python-markupsafe' 'tauthon-markupsafe' 'quilt')
source=("https://files.pythonhosted.org/packages/source/J/Jinja2/Jinja2-${pkgver}.tar.gz"
        "https://security.debian.org/debian-security/pool/updates/main/j/jinja2/jinja2_${_debver}-${_debrel}+deb11u4.debian.tar.xz")
sha512sums=('fce4f835795fe9afb622f8106f60344032a811f3f693806f31ba482f9b7c1400f93dfa1701b4db0b472cbed4b0793cb329778c8091811ef0e3b577150d28e004'
            'fcfb36c9c44bb7a1b4c31118cd6af1017d3db2b1e632c4c1bd8dfca9928052cb024f95197b0b79ef83a18ff988ddd94a9687dc19f1088561aacf614e3d2b292c')

prepare() {
  cd Jinja2-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  cd ..
  cp -a Jinja2-$pkgver{,-tauthon}
}

build() {
  cd "${srcdir}/Jinja2-$pkgver"
  python setup.py build

  cd "${srcdir}/Jinja2-$pkgver-tauthon"
  tauthon setup.py build
}

package_python-jinja() {
  pkgdesc+=" in Python"
  depends=('python-setuptools' 'python-markupsafe')
  optdepends=('python-babel: for i18n support')

  cd "${srcdir}/Jinja2-$pkgver"
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE.rst -t "$pkgdir/usr/share/licenses/$pkgname"
  install -Dm644 ext/Vim/jinja.vim -t "$pkgdir/usr/share/vim/vimfiles/syntax"
}

package_tauthon-jinja() {
  pkgdesc+=" in Tauthon"
  depends=('tauthon-setuptools' 'tauthon-markupsafe')
  optdepends=('tauthon-babel: for i18n support')

  cd "${srcdir}/Jinja2-$pkgver-tauthon"
  tauthon setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE.rst -t "$pkgdir/usr/share/licenses/$pkgname"
}