# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-idna
pkgname=('python-idna' 'tauthon-idna')
pkgver=2.10
pkgrel=1
pkgdesc="Internationalized Domain Names in Applications (IDNA)"
arch=('any')
license=('Modified-BSD')
url='https://github.com/kjd/idna'
makedepends=('python-setuptools' 'tauthon-setuptools')
source=("https://pypi.io/packages/source/i/idna/idna-$pkgver.tar.gz")
sha512sums=('83b412de2f79a4bc86fb4bdac7252521b9d84f0be54f4fb1bde1ee13a210bbfa4b1a98247affbc7921046fb117a591316c12694c1be72865767646554c5207ac')

prepare() {
   rm -r idna-$pkgver/*.egg-info
   cp -a idna-$pkgver{,-tauthon}
}

build() {
   cd "$srcdir"/idna-$pkgver
   python setup.py build

   cd "$srcdir"/idna-$pkgver-tauthon
   tauthon setup.py build
}

check() {
   cd "$srcdir"/idna-$pkgver
   python setup.py test

   cd "$srcdir"/idna-$pkgver-tauthon
   tauthon setup.py test
}

package_python-idna() {
   depends=('python')

   cd idna-$pkgver
   python setup.py install --root="$pkgdir" --optimize=1 --skip-build
   install -Dm644 LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.rst
}

package_tauthon-idna() {
   depends=('tauthon')

   cd idna-$pkgver-tauthon
   tauthon setup.py install --root="$pkgdir" --optimize=1 --skip-build
   install -Dm644 LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.rst
}

# vim:set ts=2 sw=2 et: