# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-future
pkgname=('python-future' 'tauthon-future')
pkgver=0.18.2
_debver=$pkgver
_debrel=5
pkgrel=2
url='https://python-future.org/'
arch=('any')
license=('Expat')
makedepends=('python-setuptools' 'tauthon-setuptools' 'quilt')
options=('!emptydirs')
source=("https://pypi.io/packages/source/f/future/future-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-future/python-future_$_debver-$_debrel.debian.tar.xz")
sha512sums=('91c025f7d94bcdf93df838fab67053165a414fc84e8496f92ecbb910dd55f6b6af5e360bbd051444066880c5a6877e75157bd95e150ead46e5c605930dfc50f2'
            '683a7697bfb755cba48a9a3cf8628baf4f5c253f16f2166a6059ac78fabc5fd57a45c9103029195d85b6a044a4301a91f6db4150807d4f39c67d6077aac43c56')

prepare() {
  cd "$srcdir"/future-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  cp -a "$srcdir"/future-$pkgver{,-tauthon}
}

build() {
  cd "$srcdir"/future-$pkgver
  python setup.py build

  cd "$srcdir"/future-$pkgver-tauthon
  tauthon setup.py build
}

package_python-future() {
  pkgdesc="Clean single-source support for Python"
  depends=('python')
  optdepends=('python-setuptools: futurize and pasteurize scripts')
  provides=('futurize' 'pasteurize')

  cd future-$pkgver

  python setup.py install --root="$pkgdir" --optimize=1
  install -D -m644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
}

package_tauthon-future() {
  pkgdesc="Clean single-source support for Tauthon"
  depends=('tauthon')
  optdepends=('tauthon-setuptools: futurize2 and pasteurize2 scripts')

  cd future-$pkgver-tauthon

  tauthon setup.py install --root="$pkgdir" --optimize=1

  mv "$pkgdir"/usr/bin/futurize{,-tauthon}
  mv "$pkgdir"/usr/bin/pasteurize{,-tauthon}

  install -D -m644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
}