# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=python-cycler
pkgver=0.10.0
_debver=$pkgver
_debrel=3
pkgrel=1
pkgdesc="Composable style cycles"
arch=('any')
license=('Modified-BSD')
url='https://github.com/matplotlib/cycler'
depends=('python-six' 'python-nose')
makedepends=('python-setuptools' 'quilt')
source=("https://github.com/matplotlib/cycler/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-cycler/python-cycler_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('685231d455dfdde70eb71415dfe561e07c34579d7b31ef7197f4c1441301635b387fec903d610b35406b619264f4c0cc616562de8f02b8192414c29274b63c01'
            '7bc152c9c6cd33fdacd90b20bc05b3f5ab0b5f32a02687d1d92dfdf785170ad5f9b94e96040120ca716893ca077d2f37271bc2ea5f9a34c9b1ea3821a09d0de1')

prepare() {
  cd cycler-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd cycler-$pkgver
  python setup.py build
}

package() {
  cd cycler-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
}