# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-cryptography
pkgname=('python-cryptography' 'tauthon-cryptography')
pkgver=3.1
pkgrel=2
arch=('i686' 'x86_64')
license=('Apache-2.0')
url='https://pypi.python.org/pypi/cryptography'
makedepends=('python-setuptools' 'tauthon-setuptools' 'python-six' 'tauthon-six' 'python-cffi'
             'tauthon-cffi' 'tauthon-enum34' 'python-pyasn1' 'tauthon-pyasn1' 'python-idna'
             'tauthon-idna' 'tauthon-ipaddress' 'python-asn1crypto' 'tauthon-asn1crypto' 'quilt')
source=("https://pypi.io/packages/source/c/cryptography/cryptography-${pkgver}.tar.gz")
sha512sums=('c015df3a71e4c274b2fb8fd954d264c8b56443644048139113f548c69cf83798b73c9f0993609f338044df92b609723b0281ce61ed2751309a122de22060037e')

prepare() {
  cp -a cryptography-${pkgver}{,-tauthon}
}

build() {
  cd "$srcdir"/cryptography-$pkgver
  python setup.py build

  cd "$srcdir"/cryptography-$pkgver-tauthon
  tauthon setup.py build
}

package_python-cryptography() {
  pkgdesc="A package designed to expose cryptographic recipes and primitives to Python developers"
  depends=('python-six' 'python-cffi' 'python-idna' 'python-setuptools' 'python-asn1crypto')

  cd cryptography-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE.APACHE $pkgdir/usr/share/licenses/$pkgname/LICENSE.APACHE
}

package_tauthon-cryptography() {
  pkgdesc="A package designed to expose cryptographic recipes and primitives to Tauthon developers"
  depends=('tauthon-six' 'tauthon-cffi' 'tauthon-enum34' 'tauthon-idna' 'tauthon-ipaddress'
           'tauthon-setuptools' 'tauthon-asn1crypto')

  cd cryptography-$pkgver-tauthon
  tauthon setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE.APACHE $pkgdir/usr/share/licenses/$pkgname/LICENSE.APACHE
}