# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=python-cppy
pkgver=1.1.0
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="A collection of C++ headers which make it easier to write Python C extension modules"
url='https://github.com/nucleic/cppy'
license=('Modified-BSD')
arch=('any')
depends=('python')
makedepends=('python-setuptools' 'quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/nucleic/cppy/archive/${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/c/cppy/cppy_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('b745b6fe1d02f87b8c257a73792ed583ca6e709943af567105f6ccfcf9c5eb99e9dcaaad42b0b4d6f90de2b4398bf8e5bb042798cd98e376c90e9b54ea24a212'
            'ca4418648ee55a89a111943435e28be0607470959353c264eb409fbd7c35747d5710105327dc8c44ab2206e3c6fee863ff907415994e0a84dbb9c08bec144fde')

prepare() {
  cd cppy-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd cppy-$pkgver
  python setup.py build
}

package() {
  cd cppy-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
}