# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=python-bottle
pkgver=0.13.2
_debver=$pkgver
_debrel=1.1
pkgrel=1
pkgdesc="A fast and simple micro-framework for small web-applications"
arch=('any')
url='https://bottlepy.org'
license=('Expat')
options=(!emptydirs)
depends=('python')
makedepends=('python-setuptools' 'quilt' 'python-wheel')
source=("$pkgname-$pkgver.tar.gz::https://github.com/defnull/bottle/archive/$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-bottle/python-bottle_$_debver-$_debrel.debian.tar.xz")
sha512sums=('ee9f9d90b124c0ebbfa60d0b262f2564daa485b39396cbb978d5381b7957ac09e663a0a8eb8c9d9212e3887a25502a4948c22eda1d90e1449f2e3d120d8fc833'
            '893e674ba34ac70a5c054cc0bcc301b6f687db5388920b666bb4fedbcf24aa2575a1fb0891491d4b0487e809e2cb5b9d6acc8a74d2396901550b5a89bb3a5616')

prepare() {
  cd "$srcdir"/bottle-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir"/bottle-$pkgver
  python setup.py build
}

package() {
  cd bottle-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
}