# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=python-black
pkgver=20.8b1
_debver=$pkgver
_debrel=4
pkgrel=1
pkgdesc="Uncompromising Python code formatter"
arch=('any')
url='https://github.com/psf/black'
license=('Expat')
depends=('python' 'python-appdirs' 'python-click' 'python-mypy_extensions'
         'python-pathspec' 'python-regex' 'python-toml')
makedepends=('python-setuptools-scm' 'quilt')
source=("https://files.pythonhosted.org/packages/source/b/black/black-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/b/black/black_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('f047c2a1ce759a8e19eed2e1869752bb8a63bf17a554aff5d9e834a48cd390b23918b78e01d5c36c0fb7599439d7e422847bde504ff698d53df5c5939a8870d2'
            '6c4acb2c203b9f9ad098679554c418f38e13333c4a083ab37df76eb807eb18cdea8fd35027cedaa365313f474c024bad38796762fe496586800caca01183b34f')

prepare() {
  cd "black-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/version-declaration.diff || true

    quilt push -av
  fi
}

build() {
  cd "black-$pkgver"
  python setup.py build
}

package() {
  cd "black-$pkgver"
  export PYTHONHASHSEED=0
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build

  # https://github.com/FFY00/python-install/issues/7
  sed -i 's/patched_main \[d]/patched_main/' "$pkgdir"/usr/bin/blackd

  # https://github.com/FFY00/python-install/pull/6
  chmod +x "$pkgdir"/usr/bin/*

  # license file
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}