# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=python-attrs
pkgver=20.3.0
_debver=20.3.0
_debrel=1
pkgrel=1
pkgdesc="Attributes without boilerplate."
arch=('any')
license=('Expat')
url='https://attrs.readthedocs.org/'
makedepends=('python-setuptools' 'quilt')
source=("https://pypi.io/packages/source/a/attrs/attrs-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-attrs/python-attrs_$_debver-$_debrel.debian.tar.xz")
sha512sums=('640532c6b763fd96572e5d85e93c111bebc4c5e0ff9419fe92fb51280f03acb5f9f43339f57d30659e777d5578460675c60ec0a362f9ad433893e3624ce6a931'
            '890fbd75373e4198ad69f4c75a8c248977368146baf729da8da2cfe2991c9505c451d074272c01b7c0c9d8669555fe346cdd1af2136b6f67e814516883c65c5e')

prepare() {
  cd "$srcdir"/attrs-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir"/attrs-$pkgver
  python setup.py build
}

package() {
  depends=('python')

  cd attrs-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}