# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-appdirs
pkgname=('python-appdirs' 'tauthon-appdirs')
pkgver=1.4.4
pkgrel=3
arch=('any')
url='https://github.com/ActiveState/appdirs'
license=('Expat')
makedepends=('python' 'tauthon')
source=("https://pypi.io/packages/source/a/appdirs/appdirs-$pkgver.tar.gz")
sha512sums=('8b0cdd9fd471d45b186aa47607691cf378dabd3edc7b7026a57bd6d6f57698e86f440818a5e23ba4288b35d6bb8cb6eb0106eae8aab09d8863ee15025d300883')

prepare() {
  cp -a appdirs-$pkgver{,-tauthon}
}

build() {
  cd "$srcdir"/appdirs-$pkgver
  python setup.py build

  cd "$srcdir"/appdirs-$pkgver-tauthon
  tauthon setup.py build
}

package_python-appdirs() {
  pkgdesc='A small Python module for determining appropriate platform-specific dirs, e.g. a "user data dir".'
  depends=('python')

  cd appdirs-$pkgver
  python setup.py install --root="$pkgdir/" --optimize=1
  install -Dm644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
}

package_tauthon-appdirs() {
  pkgdesc='A small Tauthon module for determining appropriate platform-specific dirs, e.g. a "user data dir".'
  depends=('tauthon')

  cd appdirs-$pkgver-tauthon
  tauthon setup.py install --root="$pkgdir/" --optimize=1
  install -Dm644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
}