# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=python-acme
pkgver=1.12.0
_debver=$pkgver
_debrel=2
pkgrel=2
pkgdesc="ACME protocol implementation in Python"
arch=('any')
license=('Apache-2.0')
url="https://github.com/certbot/certbot"
makedepends=('quilt')
depends=('python-setuptools' 'python-pyopenssl' 'python-pyrfc3339' 'python-pytz' 'python-requests'
         'python-six' 'python-josepy' 'python-requests-toolbelt')
source=("https://pypi.io/packages/source/a/acme/acme-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-acme/python-acme_${_debver}-${_debrel}+deb11u1.debian.tar.xz")
sha512sums=('1503fd1c1fb021520f1d2f35416f1cde0c7fc84fb52e808a127aea2260d1e4c1ec6427deb2384e726d18b1f9bed786100db4b45184a2de116cd35bc698e38336'
            'c72107d8140826f651ae07d58222139cf3f5426aaa20ecb3555f235edb9215bf86b837babcc2d050ea32c9195f1b30cf12b43ff5517aa995ff6740a43cd67a51')

prepare() {
  cd acme-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "${srcdir}"/debian .

    quilt push -av
  fi
}

build() {
  cd acme-$pkgver
  python setup.py build
}

package() {
  cd acme-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1
  install -D -m644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
}