# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=pugixml
pkgver=1.11.4
_debver=1.11.4
_debrel=1
pkgrel=1
pkgdesc='Light-weight, simple and fast XML parser for C++ with XPath support'
arch=('i686' 'x86_64')
url='https://pugixml.org'
license=('Expat')
depends=('gcc-libs')
makedepends=('cmake' 'quilt')
source=(https://github.com/zeux/pugixml/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/p/pugixml/pugixml_${_debver}-${_debrel}.debian.tar.xz)
sha512sums=('c83f57ef2492eee359d979597fb5089b8eca547bb9d41cfbb6bcf43d59fe75e6780b0f31dd593145ec9888c065153aba52702667e2de213fa080cd51e9e13a38'
            'b8aaf152ece26f6bc1786379e13ac41e47f769e7b93c3e43dd8204d80626a38fba346718769db02eb63f33a5cc3a65917cb7dbbc6aa505d6242e6a76a9ffa152')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
    cmake -B build -S ${pkgname}-${pkgver} \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DBUILD_SHARED_LIBS=ON
    make -C build
}

package() {
    make -C build DESTDIR="${pkgdir}" install
    install -Dm644 ${pkgname}-${pkgver}/readme.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
}