# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on publicsuffix-list

pkgname=publicsuffix
pkgver=20200627.1701
_debver=20200627.1701
_debrel=1
pkgrel=2
pkgdesc='Cross-supplier public domain suffix database'
url='https://publicsuffix.org/'
arch=('any')
license=('MPL-2.0')
makedepends=('quilt')
replaces=('publicsuffix-list')
conflicts=('publicsuffix-list')
provides=('publicsuffix-list')
source=(https://deb.debian.org/debian/pool/main/p/publicsuffix/publicsuffix_$pkgver.orig.tar.gz
        https://deb.debian.org/debian/pool/main/p/publicsuffix/publicsuffix_$_debver-$_debrel.debian.tar.xz)
sha512sums=('d36609a8fa3af120bcbcad2e895b048a6f9081ef2dd96521d67801cd5036b650ae770eb5af683d24be0a4657a7cdfd394d21856e206d903ae6349f31624b9d6d'
            'b88bb5a3f997bdf5341fa4cb529765bcd79ed046cc0c9e42306cd2775faf76102d2d88b6f0b81bfb6dbf45ab18daba999398494553b7c6124504e1c507dbdd36')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

package() {
  cd $pkgname-$pkgver

  install -Dm 644 public_suffix_list.dat tests/test_psl.txt -t $pkgdir/usr/share/$pkgname
  ln -s public_suffix_list.dat $pkgdir/usr/share/$pkgname/effective_tld_names.dat

  install -Dm 644 LICENSE -t $pkgdir/usr/share/licenses/$pkgname
}