# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=ptlib
pkgver=2.10.11
_debver=2.10.11~dfsg
_debrel=2.1
pkgrel=6.hyperbola3
pkgdesc="Portable Windows Library, with libsndio recommendation and with libsndio and LibreSSL support"
arch=('i686' 'x86_64')
url="http://www.opalvoip.org"
license=('MPL-1.0')
depends=('sdl' 'libsndio' 'v4l-utils' 'libldap')
makedepends=('quilt')
optdepends=('sndio: audio and MIDI server')
replaces=('pwlib')
conflicts=('pwlib')
source=(https://downloads.sourceforge.net/opalvoip/ptlib-$pkgver.tar.bz2
        https://deb.debian.org/debian/pool/main/p/ptlib/ptlib_$_debver-$_debrel.debian.tar.xz
        ptlib-2.10.11-bison_fixes-2.patch
        patch-src_ptclib_pssl_cxx.patch
        sndio.patch
        MPL-1.0.txt)
sha512sums=('ac8af8962330abf11986ccb863be0990c2e78ae611666d17c68068b72c4a5ea523ba74c55566284c3549e2346e407ccfffb5cc509fbf6ef19f1eb51dcb8b5f15'
            'b0eec5a458e4b4e464e7864c3c22a54c92b5640855c8881bf7a7a031780df15a8f7cdd3c4f3a0799ed7daaa12abbc6c3c384486537cd46e8c24dde629f53dd5e'
            'd02ee95f98082ab6a6f317d4e78b5a2dd7de2d5491aa55dad1ccbb0d93542744b48ccfdf7b4702dc8fd76848da2f43f189f530fc511eec20198b83bd413dd0d0'
            'b2db3cac3678cd030cc345693f9b93e23b6c4ad7399dbb188dd721859c287b8e2e3af04ddcd3628352c90d676eaa0b2c310f8f8569e1b74df4ea36af4b70596b'
            'e5a9e62ddb6e81f0b6ff34e32df90dc0ac182378190fa615cf515836773b6f63d9c33d020cf7700a28238090aea45a266ffddf881f425746ffe872575cf6ef7c'
            'ff62561d65d0b269b9a289f964a73099cc4456cb25927fc19734b0896735054a5023b6b44d4ddda17ece0a1f42050581f66ba0b9afaffa52538ec143bc908cf7')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply and seems unimportant
    rm -v debian/patches/bison-fix || true
    rm -v debian/patches/gcc-5_support || true
    rm -v debian/patches/hurd-fix || true
    rm -v debian/patches/no-sslv3 || true
    rm -v debian/patches/ppc64el-arm64-mips64.diff || true

    quilt push -av
  fi
  patch -Np1 -i ../ptlib-2.10.11-bison_fixes-2.patch
  patch -Np0 -i ../patch-src_ptclib_pssl_cxx.patch
  patch -Np1 -i ../sndio.patch
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --libdir=/usr/lib \
      --sysconfdir=/etc --localstatedir=/var \
      --enable-opal --enable-plugins \
      --enable-oss --enable-v4l2 \
      --disable-avc --enable-sdl \
      --enable-ipv6 --enable-v4l \
      --disable-dc --disable-odbc \
      --enable-expat --enable-httpforms \
      --disable-pulse --enable-sndio
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
  install -Dm644 $srcdir/MPL-1.0.txt $pkgdir/usr/share/licenses/$pkgname/MPL-1.0.txt
}