# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=proxychains
_realpkgname=proxychains-ng
pkgver=4.16
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="A hook preloader that allows to redirect TCP traffic of existing dynamically linked programs through one or more SOCKS or HTTP proxies"
arch=('i686' 'x86_64')
url='https://github.com/rofl0r/proxychains-ng'
license=('GPL-2')
depends=('glibc')
makedepends=('quilt')
backup=('etc/proxychains.conf')
source=("https://github.com/rofl0r/proxychains-ng/archive/v${pkgver}/${_realpkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/proxychains-ng/proxychains-ng_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('a929a6caa0e648e23eadb393ef7d0930ff92a84d77a8eff940b83e45f9410dc6bf6be225554254f63bc215bb043a024d4e82274eb17330cae41985d64be1050e'
            '5ae78cdb9dc2f4a0740f42fc62fee5a6595876f7d64aba39c21858be7e456350fa2be6866f85e411309898eed4d61baaef010b77e235be0b3dd295ee9a258e09')

prepare() {
  cd proxychains-ng-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd proxychains-ng-$pkgver
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc
  make
}

package() {
  cd proxychains-ng-$pkgver
  make DESTDIR="$pkgdir/" install install-config
  ln -s proxychains4 "$pkgdir/usr/bin/proxychains"
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}