# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=prboom
pkgver=2.5.0
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="A free and libre game engine which provides a program to play Doom levels."
url='http://prboom.sourceforge.net/'
license=('GPL-2')
depends=('libpng' 'sdl_mixer' 'sdl_net' 'glu')
makedepends=('mesa')
groups=('games')
source=("https://downloads.sourceforge.net/prboom/$pkgname-$pkgver.tar.gz"
        "fix-libpng.patch")
sha512sums=('9e25b55047c66931ea010751fb64484e466395b04dfb738ed9dc515bd8b78e1124a337da33bf7be6e97280016ed1f01c852d8bc12704bdb82074488d7b5d2894'
            '40e55394b065c6cc383d331343a6a372413e6a1cd7c5cc463a53e4cbe440f7e2e9d0ff4ceff63fafcef534fb7f2ef1eb3531438de457134c3fcc8201f442b390')

prepare() {
  cd $pkgname-$pkgver

  # allow building with newer libpng
  patch -p1 < $srcdir/fix-libpng.patch
}

build() {
  cd $pkgname-$pkgver

  CFLAGS="$CFLAGS -fcommon" \
  ./configure \
    --prefix=/usr \
    --disable-i386-asm \
    --disable-cpu-opt
  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir/" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}